Magic Lists, voice enabled list boxes

magic lists setup up     magic lists     create magic list     delete magic list     utility functions    

This is an example of Advanced Scripting application that creates voice-enabled list boxes. Configuration is stored in the registry. There is an included file with a group of utility functions and a group of scripts.

The lists are stored in text files.

magic lists set up

MyCommand Name	magic lists set up
Description	show the setup dailog for magic lists
Availability	Global
Command Type	Advanced Scripting

This script creates a dialog to configure the magic lists application.

'#Uses "c:\NatSpeak support\swMagicLists.bas"

Sub Main
	Begin Dialog UserDialog 400,203,"Magic Lists Configuration",.dlgFunc ' %GRID:10,7,1,1
		Text 20,14,200,14,"Folder to store magic list files",.Text1
		TextBox 20,35,360,21,.txtPath
		Text 20,140,190,14,"Maximum number of list items",.Text2
		TextBox 20,161,90,21,.txtMax
		OKButton 270,140,90,21
		CancelButton 270,168,90,21
		Text 20,70,170,14,"Filepath to default editor",.Text3
		TextBox 20,84,360,21,.txtEditor
	End Dialog

	Dim dlg As UserDialog



	If Dialog(dlg) = -1 Then
		' save settings in registry
		SaveSetting( "swUtils", "magiclist", "path", dlg.txtPath )
		SaveSetting( "swUtils", "magiclist", "max", dlg.txtMax )
		SaveSetting( "swUtils", "magiclist", "editor", dlg.txtEditor )
		DragonMsg "Magic list configuration saved"
	Else
		DragonMsg "Action cancelled"
	End If

End Sub

Rem See DialogFunc help topic for more information.
Private Function dlgFunc(DlgItem$, Action%, SuppValue&) As Boolean
	Select Case Action%
	Case 1 ' Dialog box initialization
		' get settings from registry
		DlgText( "txtPath", GetSetting( "swUtils", "magiclist", "path" ) )
		DlgText( "txtMax", GetSetting( "swUtils", "magiclist", "max" ) )
		DlgText( "txtEditor", GetSetting( "swUtils", "magiclist", "editor" ) )
	Case 2 ' Value changing or button pressed
		Rem dlgFunc = True ' Prevent button press from closing the dialog box
	Case 3 ' TextBox or ComboBox text changed
	Case 4 ' Focus changed
	Case 5 ' Idle
		DlgFocus "txtPath"
		Rem Wait .1 : dlgFunc = True ' Continue getting idle actions
	Case 6 ' Function key
	End Select
End Function

MyCommand Name	create magic list
Description	create a magic list
Availability	Global
Command Type	Advanced Scripting

'#Uses "c:\NatSpeak support\swMagicLists.bas"

Sub Main
	Dim ok As Boolean
	Dim msg As String

  Begin Dialog UserDialog 300, 300, 390,322,"Create New List",.DlgFunc ' %GRID:10,7,1,1
		Text 20,14,90,14,"Name of List",.lblName
		TextBox 20,35,340,21,.txtName 'Name of List
		Text 20,63,70,14,"Filename",.Text2
		TextBox 20,84,340,21,.txtFilename 'Filename
		Text 20,119,140,14,"Initial contents"
		TextBox 20,140,340,140,.tbContents,1 'Contents
		OKButton 140,294,90,21
	End Dialog
	Dim dlg As UserDialog

	If Dialog(dlg) = -1 Then

		ok = True

		' validation
		If Len(dlg.txtName) < 1 Then
			ok = False
			msg = msg + Chr(13) + Chr(10) + "You must supply a list name"
		End If

		If Len(dlg.txtFilename) < 1 Then
			ok = False
			msg = msg + Chr(13) + Chr(10) + "You must supply a filename"
		End If

		If FileExist( magicListPath(dlg.txtFilename) ) Then
			ok = False
			msg = msg + Chr(13) + Chr(10) + "That list already exists!"
		End If

		' create the list
		If ok Then
			msg = magicListCreate( dlg.txtName, dlg.txtFilename, dlg.tbContents )
		End If

		If Len(msg) > 0 Then
			MsgBox msg
		End If


	End If

End Sub

Rem See DialogFunc help topic for more information.
Private Function DlgFunc(DlgItem$, Action%, SuppValue&) As Boolean
	Select Case Action%
	Case 1 ' Dialog box initialization
	Case 2 ' Value changing or button pressed
		Rem DlgFunc = True ' Prevent button press from closing the dialog box
	Case 3 ' TextBox or ComboBox text changed
	Case 4 ' Focus changed
	Case 5 ' Idle
		DlgFocus "txtName"
		Rem Wait .1 : DlgFunc = True ' Continue getting idle actions
	Case 6 ' Function key
	End Select
End Function

MyCommand Name	magic lists
Description	display a voice enabled list box with a list of lists
Availability	Global
Command Type	Advanced Scripting

'#Uses "c:\NatSpeak support\swMagicLists.bas"


Sub Main

	Dim result, s the thenelection
	Dim max As Long
	max = Int( GetSetting("swUtils", "magiclist", "max", "100") )

	Dim ListArray() As String
	Dim vArray() As String

	ReDim ListArray( max )
	ReDim vArray( max )

	' get the list of lists
	magicListList( ListArray(), vArray() )

	' show dialog
	result = dlgMagicListBox( ListArray() )

	' dialog ok?  use selection to re-populate a new dialog
	If result >= 0 Then

		' save selected list
		selection = vArray(result)

		' make certain the array is clean
		ReDim ListArray( max )
		ReDim vArray( max )

		magicListGet( selection, ListArray(), vArray() )

		result = dlgMagicListbox( ListArray() )
		Clipboard vArray( result )
		DragonMsg "'" + vArray( result ) + "' added to clipboard"
	End If
End Sub



'
' recognize custom voice commands
'
Public Sub VoiceCommand_CommandRecognize(Command As String, ID As Long, Action As String, ListResults As DNSTools.DgnStrings)
	DragonMsg Str(ID) + " " + Command
	Dim amt
	amt = ID
	If amt > 0 Then
		SendKeys "{Down " + Str(amt) + "}"
		Wait .05
	End If
	SendKeys "{Enter}"
End Sub

in

MyCommand Name	delete magic list
Description	delete a magic list
Availability	Global
Command Type	Advanced Scripting

'#Uses "c:\NatSpeak support\swMagicLists.bas"


Sub Main
	Dim result, selection
	Dim max As Long
	Dim strEditor As String
	Dim ListArray() As String
	Dim vArray() As String

	max = magicListMax()

	ReDim ListArray( max )
	ReDim vArray( max )

	' get the list of lists
	magicListList( ListArray(), vArray() )

	' show dialog
	result = dlgMagicListBox( ListArray() )

	' dialog ok?  use selection to re-populate a new dialog
	If result >= 0 Then

		' save selected list
		selection = vArray(result)
		magicListDelete( selection )
		DragonMsg "delete magic list: '" + vArray( result ) + "'"


	End If
End Sub



'
' recognize custom voice commands
'
Public Sub VoiceCommand_CommandRecognize(Command As String, ID As Long, Action As String, ListResults As DNSTools.DgnStrings)
	DragonMsg Str(ID) + " " + Command
	Dim amt
	amt = ID
	If amt > 0 Then
		SendKeys "{Down " + Str(amt) + "}"
		Wait .05
	End If
	SendKeys "{Enter}"
End Sub

Utility Functions

Here is the code for the included file used in the above scripts. In the above scripts it is saved as c:\Natspeak support\swMagicLists.bas. If you save the file in a different location you will need to update the #Uses line to the filepath where you saved it in each of the above scripts.

' swMagicLists.bas
'
' Magic Lists - Voice enabled selection lists for
' Dragon NaturallySpeaking Professional
'
' include this file by using the statement '#Uses "c:\yourpath\swMagicLists.bas"
'
' 
' (c) 2005 Sean Wenzel All rights reserved http://sean.wenzel.net/
'
' This software is licensed under the following license agreement: 
' http://www.gnu.org/copyleft/gpl.html
'
' there is no express or implied warranty, there are likely bugs, 
' your mileage will most certainly vary
'
' in some functions error checking is minimal
'
' 

Option Explicit


' fso constants
Public Const ForReading = 1
Public Const ForWriting = 2
Public Const ForAppending = 8


'  
' Display a message in the Dragon status bar
'
Function DragonMsg(s As String)
	EngineControl.DragonBar.ShowMessage showmessageNoBeep, s
End Function



'
' magic list utility function, generates file path of a given list
'
Public Function magicListPath( ByVal name As String ) As String
	magicListPath = GetSetting( "swUtils", "magiclist", _
								"path", "c:\" ) + "\" + name + ".txt" 
End Function


'
' create a new magic list
'
Public Function magicListCreate( ByVal name As String, ByVal filename As String, ByVal contents As String )

  	Dim fso, f
	Set fso = CreateObject("Scripting.FileSystemObject")
	
	' add the entry to the list of lists file
	On Error Goto X
	Set f = fso.OpenTextFile( magicListPath( "lists" ), ForAppending, False )
	Goto Y
	X: 
		DragonMsg "Error=" +  Err
		Err.Clear
		Set f = fso.CreateTextFile( magicListPath("lists"), False )
	Y:
	f.WriteLine( name + "|" + filename )
	f.Close

	' create the new list and populate with initial content
	Set f = fso.CreateTextFile( magicListPath( filename ), False )
	f.Write( contents )
	f.Close

End Function


'
' add item to magic list
'
Public Function magicListAdd( ByVal listname As String, ByVal name As String, ByVal value As String ) As String
	
	Dim fso, f
	Set fso = CreateObject("Scripting.FileSystemObject")

	' add the entry to the lists file
	Set f = fso.OpenTextFile( magicListPath( listname ), ForAppending, False )
	f.WriteLine( name + "|" + value )
	f.Close

End Function



' 
'
' dialog function for dlgMagicListbox
'
Private Function DlgMagicFunc(DlgItem$, Action%, SuppValue&) As Boolean
	Select Case Action%
	Case 1 ' Dialog box initialization
	Case 2 ' Value changing or button pressed
		Rem DlgFunc = True ' Prevent button press from closing the dialog box
	Case 3 ' TextBox or ComboBox text changed
	Case 4 ' Focus changed
	Case 5 ' Idle
		Rem Wait .1 : DlgFunc = True ' Continue getting idle actions
		DlgFocus( "lbList" )
		Case 6 ' Function key
	End Select
End Function


' create dialog box containing a list box
' populate with passed array and setup custom voice menu
' show the dialog and return result
'
Function dlgMagicListbox( ByRef list() As String ) As Integer
	Dim i, vMenu

	Set vMenu = VoiceCommand.MenuCreate( "Magic list", "Magic", dgnlangUSEnglish, "", vcmdmc_CREATE_TEMP )

	' iterate through array and build voice menu commands on the fly
	i = 0
	Do Until Len(list(i)) < 1
		vMenu.Add i, list(i), "", ""
		i = i + 1
	Loop

	vMenu.Active = True

	Begin Dialog UserDialog 200,200,370,294,"Magic Lists",.DlgMagicFunc ' %GRID:10,7,1,1
		ListBox 20,14,330,224,list(),.lbList
		OKButton 130,252,90,21
	End Dialog
	Dim dlg As UserDialog
	If Dialog(dlg) = -1 Then
		dlgMagicListbox = Str(dlg.lbList)
	Else
		dlgMagicListbox = -1
	End If
End Function


'
' get max array size
'
Function magicListMax() As Long
	magicListMax = Int( GetSetting("swUtils","magiclist","max","100") )
End Function

'
' load two arrays with the magic list of lists
'
Function magicListList( ByRef ListArray() As String, ByRef DataArray() As String ) As Long

	Dim fso, f, i, s

	' read list of lists and populate arrays of values

	Set fso = CreateObject("Scripting.FileSystemObject")
	Set f = fso.OpenTextFile( magicListPath("lists"), ForReading, False )
	i = 0
	Do While Not f.AtEndOfStream

		' read a line of the file
		s = f.ReadLine

		' split the lines and add to array
		ListArray(i) = Mid( s, 1, InStr( s, "|" ) - 1 )
		DataArray(i) = Mid( s, InStr( s, "|" ) + 1, Len(s) )

		' increment counter
		i = i + 1

	Loop
	f.Close

	' return # of items in list
	magicListList = i
End Function


'
' get the contents of a magic list
'
Function magicListGet ( ByVal name As String, ByRef ListArray() As String, ByRef DataArray() As String ) As Long

	Dim fso, f, i, s

	' read list of lists and populate arrays of values

	Set fso = CreateObject("Scripting.FileSystemObject")
	Set f = fso.OpenTextFile( magicListPath(name), ForReading, False )
	i = 0
	Do While Not f.AtEndOfStream

		' read a line of the file
		s = f.ReadLine

		' split the lines and add to array
		If InStr( s, "|" ) > 0 Then
			ListArray(i) = Mid( s, 1, InStr( s, "|" ) - 1 )
			DataArray(i) = Mid( s, InStr( s, "|" ) + 1, Len(s) )
		Else
			ListArray(i) = s
			DataArray(i) = s
		End If

		' increment counter
		i = i + 1

	Loop
	f.Close

	' return # of items in list
	magicListGet = i

End Function


'
' check if the file exists
'
Public Function FileExist(asPath As String) As Boolean
	'
	'Checks for an existing File,
	'returns True or False
	'
	If Dir(asPath) = "" Then
		FileExist = False
	Else
		FileExist = True
	End If
End Function


'
' edit a magic list by launching user selected editor
'
Public Function magicListEdit( list As String ) As Long
	Dim strEditor As String
	strEditor = GetSetting( "swUtils", "magiclist", "editor", "notepad.exe" ) _
						+ " " + magicListPath(list)
	
	DragonMsg( strEditor )
	Shell( strEditor, vbNormalFocus )
  magicListEdit = 0
End Function



'
' delete a magic list
' 
Public Function magicListDelete( list As String ) As Long

	Dim fso, f, i, s
	Dim oldf, nf

	' read list of lists and populate arrays of values

	Set fso = CreateObject("Scripting.FileSystemObject")
	
	' create back of list of lists
	fso.CopyFile magicListPath("lists"), magicListPath("old_lists")
  fso.CopyFile magicListPath(list), magicListPath( "old_" + list )

	' rewrite list of lists
	Set oldf = fso.OpenTextFile( magicListPath("old_lists"), ForReading, False )
  Set nf = fso.CreateTextFile( magicListPath("lists"), True )
 
	i = 0
	Do While Not oldf.AtEndOfStream

		' read a line of the file
		s = oldf.ReadLine

		if ( InStr( s, list ) = 0 ) Then
			 nf.WriteLine(s)
		Else
				if InStr(s,list) > 1 Then
					 nf.WriteLine(s)
				End If
		End If

		' increment counter
		i = i + 1

	Loop
	oldf.Close
	nf.Close


	' delete list file
	fso.DeleteFile magicListPath(list)


End Function

magic lists setup up     magic lists     create magic list     delete magic list     utility functions